以網域系統管理員的身份登入。

按一下 [開始] 按鈕，指向 [所有程式]，指向 [附屬應用程式]，然後按一下 [命令提示字元]。

在 [命令提示字元] 中，輸入：

ldifde -f marketing.ldf -s hq-con-dc-01 -d "ou=marketing,ou=accounts,dc=contoso,dc=com" -p subtree -r "(objectCategory=CN=Person,CN=Schema,CN=Configuration,DC=contoso,DC=com)"

按 Enter 鍵。結果應該與圖 1 中顯示的內容相似。

圖 1. 匯出目錄資料
檢視大圖

上 述命令使用以下方法來建立一個名為 Marketing.ldf 的 LDIF 檔案：連接到名為 HQ-CON-DC-01 的伺服器，並對 Marketing OU 執行子樹狀目錄搜尋以尋找類別為 Person 的所有物件。輸出檔案將位於目前使用者 Documents and Settings 目錄的根目錄中。

注意：objectCategory 是用於提高搜尋效能的索引屬性。

您 可以使用該 LDIF 檔案執行大量匯入，將 Marketing OU 中的所有物件匯入到與 LDAP 相容的任何其他目錄中。某些屬性可能不適用於其他的 LDAP 實作。尤其在使用該機制將物件匯入到其他 Active Directory 中時，由於在建立物件期間將自動生成某些屬性，因此必須將這些屬性省略。（如果沒有明確省略它們，操作將會失敗。）

例如，除了新增參數 –m 外，用於省略這些屬性的 LDIFDE 命令與上述命令相同。

ldifde -f marketing.ldf -s hq-con-dc-01 -d "ou=marketing,ou=accounts,dc=contoso,dc=com" -p subtree -r "(objectCategory=CN=Person,CN=Schema,CN=Configuration,DC=contoso,DC=com)" –m

按一下 [開始] 按鈕，指向 [所有程式]，指向 [附屬應用程式]，然後按一下 [命令提示字元]。

在命令提示字元下，輸入以下命令以擷取所需的項目。

ldifde -f marketing.ldf -s hq-con-dc-01 -d "ou=marketing,ou=accounts,dc=contoso,dc=com" -p subtree –r "(objectCategory=CN=Person,CN=Schema,CN=Configuration,DC=contoso,DC=com)" -l "1,st,streetaddress,postalcode"

注意：在通用網路基礎結構指南中，沒有為 Marketing OU 內的使用者物件定義城市、省、地址以及郵遞區號的項目。建議在執行此匯出之前，為 Marketing OU 中的每個使用者物件填入這些欄位。

按 Enter 鍵。

使用「記事本」打開 marketing.ldf 文件。

注意：如果您使用資料填入每個使用者物件，則結果應該與圖 2 中顯示的內容相似。

圖 2. 檢查 LDF 檔案

在「記事本」中，修改 Marketing.ldf 中的每個使用者物件項目，使之與圖 3 的內容相似。注意：必須將檔案儲存為 .ldf 文件。

圖 3. 修改 LDF 匯入檔案

關閉「記事本」。在 [命令提示字元] 視窗中，輸入：

ldifde –i -f marketing.ldf -s hq-con-dc-01

按 Enter 鍵。結果應該與圖 4 中顯示的內容相似。

圖 4. 成功匯入 LDF 檔案

若要確認已據此修改了使用者物件屬性，請使用 [Active Directory 使用者和電腦] 嵌入式管理單元。（有關使用該嵌入式管理單元的說明，請參閱 Active Directory 管理逐步指南。）

按一下 [開始] 按鈕，按一下 [執行]，輸入 Notepad Newuser.ldf，然後按一下 [確定]。在出現提示時，按 [是] 建立新的檔案。

將以下文字新增到檔案中。

dn: CN=Pilar Ackerman,OU=Marketing,OU=Accounts,DC=contoso,DC=com

changetype: add

cn: Pilar Ackerman

objectClass: user

samAccountName: Pilar

givenName: Pilar

sn: Ackerman

儲存 newuser.ldf 檔案，然後將其關閉。繼續進行使用者物件建立之前，檢查是否將檔案儲存到了 Documents and Settings 目錄中。

在 [命令提示字元] 視窗中，輸入以下內容。

ldifde –i -f newuser.ldf -s hq-con-dc-01

按 [Enter] 鍵。完成後， [命令提示字元] 視窗將確認修改（如圖 5 所示）。

圖 5. 新增新使用者

按一下 [開始] 按鈕，按一下 [執行]，輸入 [Notepad Deleteuser.ldf]，然後按一下 [確定]。在出現相應提示時，按 [確定] 建立新的檔案。

將以下文字新增到檔案中。

dn: CN=Pilar Ackerman,OU=Marketing,OU=Accounts,DC=contoso,DC=com

changetype: delete

儲存 deleteuser.ldf 文件，然後將其關閉。

在 [命令提示字元] 視窗中，輸入以下內容。

ldifde –i -f deleteuser.ldf -s hq-con-dc-01

按一下 [開始] 按鈕，按一下 [執行]，輸入 [Notepad export.vbs]，然後按一下 [確定]。在出現相應提示時，按 [確定] 建立新的檔案。將以下文字複製到 [export.vbs] 中。

'Global variables
    Dim oContainer
    Dim OutPutFile
    Dim FileSystem
'Initialize global variables
    Set FileSystem = WScript.CreateObject("Scripting.FileSystemObject")
    Set OutPutFile = FileSystem.CreateTextFile("marketing.txt", True) 
    Set oContainer=GetObject("LDAP://OU=Marketing,OU=Accounts,DC=contoso,DC=com")
'Enumerate Container
    EnumerateUsers oContainer
'Clean up
    OutPutFile.Close
    Set FileSystem = Nothing
    Set oContainer = Nothing
    WScript.Echo "Finished"
    WScript.Quit(0)
Sub EnumerateUsers(oCont)
    Dim oUser
    For Each oUser In oCont
        Select Case LCase(oUser.Class)
               Case "user"
                    If Not IsEmpty(oUser.distinguishedName) Then
                       OutPutFile.WriteLine "dn: " & oUser.distinguishedName
                    End If
                    If Not IsEmpty(oUser.name) Then
                       OutPutFile.WriteLine "name: " & oUser.Get ("name")
                    End If
                    If Not IsEmpty(oUser.streetAddress) Then
                       OutPutFile.WriteLine "streetAddress: " & oUser.streetAddress
                    End If
                    If Not IsEmpty(oUser.l) Then
                       OutPutFile.WriteLine "l: " & oUser.l
                    End If
                    If Not IsEmpty(oUser.st) Then
                       OutPutFile.WriteLine "st: " & oUser.st
                    End If
                    If Not IsEmpty(oUser.postalcode) Then
                       OutPutFile.WriteLine "postalcode: " & oUser.postalcode
                    End If
               Case "organizationalunit", "container"
                    EnumerateUsers oUser
        End Select
        OutPutFile.WriteLine
    Next
End Sub

儲存 export.vbs，然後關閉「記事本」。

在 [命令提示字元] 視窗中，輸入 export.vbs，然後按 [Enter] 鍵。

按一下 [開始] 按鈕，按一下 [執行]，輸入 [Notepad modify.vbs]，然後按一下 [確定]。在出現相應提示時，按 [確定] 建立新的檔案。將以下文字複製到 [modify.vbs] 中。

Dim oContainer
    Set oContainer=GetObject("LDAP://OU=Marketing,OU=Accounts,DC=contoso,DC=com")
ModifyUsers oContainer
'cleanup
    Set oContainer = Nothing
    WScript.Echo "Finished"
    WScript.Quit
Sub ModifyUsers(oObject)
    Dim oUser
    oObject.Filter = Array("user")
    For Each oUser in oObject
        oUser.Put "st","Washington"
        oUser.Put "streetAddress","One Microsoft Way"
        oUser.Put "postalCode","98052"
        oUser.Put "l","Redmond"
        oUser.SetInfo
    Next
End Sub

儲存 modify.vbs，然後關閉「記事本」。

在 [命令提示字元] 視窗中，輸入 modify.vbs，然後按 [Enter] 鍵。

按一下 [開始] 按鈕，按一下 [執行]，輸入 [Notepad add.vbs]，然後按一下 [確定]。在出現相應提示時，按 [確定] 建立新的檔案。將以下文字複製到 [add.vbs] 中。

Dim oContainer
Dim oUser
Set oContainer=GetObject("LDAP://OU=Marketing,OU=Accounts,DC=contoso,DC=com")
'Create user
        Set oUser = oContainer.Create("User","CN=Pilar Ackerman") 
'Assign values to user attributes
        oUser.Put "samAccountName","Pilar"
        oUser.Put "givenName","Pilar"
        oUser.Put "sn","Ackerman"
        oUser.Put "userPrincipalName","pilar@contoso.com"
        oUser.SetInfo
'Clean up
Set oUser = Nothing
Set oContainer = Nothing
WScript.Echo "Finished"
WScript.Quit

儲存 add.vbs，然後關閉「記事本」。

在 [命令提示字元] 視窗中，輸入 add.vbs，然後按 [Enter] 鍵。

按一下 [開始] 按鈕，按一下 [執行]，輸入 [Notepad delete.vbs]，然後按一下 [確定]。在出現相應提示時，按 [確定] 建立新的檔案。將以下文字複製到 [delete.vbs] 中。

Dim oContainer
    Set oContainer=GetObject("LDAP://OU=Marketing,OU=Accounts,DC=contoso,DC=com")
'Delete user
    oContainer.Delete "user","CN=Pilar Ackerman"
'Clean up
Set oContainer = Nothing
WScript.Echo "Finished"
WScript.Quit

儲存 delete.vbs，然後關閉「記事本」。

在 [命令提示字元] 視窗中，輸入 delete.vbs，然後按 [Enter] 鍵。